thermal convection load giving a 'misleading' error
vkr535
Member
Hello Team,
I was performing 1-d thermal analogy based diffusion analysis, using link33 and surf151 elements. I ran identical inputs both in 17.2 and 201. It worked fine in 17.2, but gave an error(below) in 201. I didn't check for other versions like 180 or 190.
*** ERROR *** CP = 0.742 TIME= 14:35:20
Element 4 has a convection surface referencing a nonexistent HF
material property for material number 0.
--> Firstly, the above error is confusing and not clear what it meant.
--> Secondly, this error trap comes when the convection load was negative. But I don't think it's an issue, as it ran without any errors in 17.2
--> This error also occurs if I replace the link and surface effect elements and instead use traditional solid70 and apply convection load directly on the base element.
In short, it appears that sign of convection load is causing this issue. Could you please take a look into this issue and let me know the possible workaround for the newer versions to work.
Below is the input I used to reproduce the error.
FINISH
/CLEAR,NOSTART
/filname,therm_1d
/PREP7
LENGTH=2e-03
HEIGHT=LENGTH
THICK=HEIGHT
esize=HEIGHT
area=HEIGHT*THICK
/com, material:-1
dccstinter_1=area*1
mp,kxx,1,6e-04
mp,c,1,20
mp,dens,1,1
/com, material:-2
dccstinter_2=area*(-1)
mp,kxx,2,8e-04
mp,c,2,40
mp,dens,2,1
/com, geometry and meshing
ET,1,link33
ET,2,link33
et,3,surf151
keyo,3,8,4
et,4,surf151
keyo,4,8,4
r,1,area
k,1,-0.5*LENGTH,
k,2,0,0,0
k,3,0.5*LENGTH,
l,1,2
l,2,3
lglue,1,2
esize,esize
type,1
real,1
mat,1
lmesh,1
type,2
real,1
mat,2
lmesh,2
/com, surface effect element modeling
esel,s,type,,1
nsle
type,3
mat,3
real,3
esurf
allsel,all,all
esel,s,type,,2
nsle
type,4
mat,4
real,4
esurf
allsel,all,all
ini_temp=358 ! initial temperature
tunif,ini_temp
save
FINISH
/SOLU,
ANTYPE,TRANS
KBC,0
nsel,s,loc,x,0.5*LENGTH
nsel,a,loc,x,-0.5*LENGTH
d,all,temp,0
allsel,all,all
/com, surface load for elm-1
esel,s,type,,3
sfe,all,1,conv,2,0.0 ! no heat generation
sfe,all,1,conv,,dccstinter_1
allsel,all,all
/com, surface load for elm-2
esel,s,type,,4
sfe,all,1,conv,2,0.0 ! no heat generation
sfe,all,1,conv,,dccstinter_2
allsel,all,all
OUTRES,ALL,ALL
TIME,1
NSUBS,1,1,1
solve
FINISH
/POST1
SET,LAST
prns,temp ! NODAL CONCENTRATION PLOT AT TIME=60seconds
fini
Best Answer
-
Kai
Forum Coordinator
Hi, below is some old comments related to this problem.
A negative film coefficient (heat transfer coefficient) is usually considered non-physical since it would imply that if the bulk temperature is hotter than the surface temperature, heat would be removed rather than added to the system.
That being said, however, a negative film coefficient can be defined by using the material property HF lookup table. With the SF family of commands, specify a value of "-N", where N is the material ID of MP,HF. Then, one can define constant or temperature-dependent film coefficients with values in MP,HF (see also MPTEMP and MPDATA commands).
Since a negative value for film coefficient in the "SF" family of commands refers to the material ID of a lookup table in MP,HF, a user cannot specify negative film coefficients directly. Also, tabular loads cannot be used, either, as evaluated negative values are also assumed to be pointing to the MP,HF material ID number.
Answers
Hi, below is some old comments related to this problem.
A negative film coefficient (heat transfer coefficient) is usually considered non-physical since it would imply that if the bulk temperature is hotter than the surface temperature, heat would be removed rather than added to the system.
That being said, however, a negative film coefficient can be defined by using the material property HF lookup table. With the SF family of commands, specify a value of "-N", where N is the material ID of MP,HF. Then, one can define constant or temperature-dependent film coefficients with values in MP,HF (see also MPTEMP and MPDATA commands).
Since a negative value for film coefficient in the "SF" family of commands refers to the material ID of a lookup table in MP,HF, a user cannot specify negative film coefficients directly. Also, tabular loads cannot be used, either, as evaluated negative values are also assumed to be pointing to the MP,HF material ID number.
Hello Team,
Thank you for the response. I checked giving negative values to HF in MP command and its working now and clean.