Wenlong
Ansys Employee

Hi 


Please post the error message in another thread. Maybe titled as "EREINF error message", so that it can be better viewed by others. But here is the command I use: 


finish
/prep7

!
!
! Get the maximum element type id and section id
!
!
*get, typid, elem, 0, typm
*get, secid, secp, 0, num, max

sectypeid = secid + 1 ! Create a new section id by shifting the max by 1
etype_id = typid + 1 ! Create a new type id by shifting the max by 1

!
!
! Define the reinforcement section type and Mesh200 element type
!
!

secarea = 50 ! Define a section area for the reinforcement

sectype, sectypeid, reinf, discrete ! Define a discrete reinf section
secdata, steel_mat_id, secarea, mesh ! Define the section properties

et, etype_id, 200, 2 ! Define a new element type

!
!
! Generate Mesh200 elements
!
!

cmsel, s, rebars, elem ! Select the name selection "rebars".
! The name selection has to be bodies instead of edges
emodify, all, type, etype_id ! Change the element type to Mesh200
emodify, all, secnum, sectypeid ! Change the section to discrete reinf

!
!
! Generate Reinf264 elements based on Mesh200 and solid elements
!
!

cmsel, a, concrete, elem ! Add concrete to the selection
EREINF ! Generate reinforcement elements

esel,s,ename,,mesh200 ! Select the Mesh200 elements
edele,all ! Delete the Mesh200 elements
FINISH

allsel,all
/SOLU
OUTRES,ALL,all

 


Thanks,


Regards,


Wenlong