August 31, 2023 at 3:57 pm
Bill Bulat
Ansys Employee

Hi Yunpeng,

Your input does not run without "nodes1.dat" file. If it helps, I once created the 3D test case below that works (it solves in less than a minute). It does not use element mesh metrics as a criterion for remeshing. Instead, it uses element energy.

 

 

fini
/cle
 
/sys,del file*.png
 
/vup,1,z
/vie,1,3,2,1
 
 
C***************************************************
C*** PARAMETERS
C***************************************************
k_nlad=1
 
l=0.100
w=0.040
t=0.010
r=0.015
 
x_cut=1.5*r
 
E=2e11
Sy=E/100
E2=E/25
nu=0.3
 
theta_pilot=15*(acos(-1)/180)
 
 
C***************************************************
C*** MODEL
C***************************************************
/prep7
n,1,l/2 ! PILOT NODE
bloc,-l/2,l/2,-w/2,w/2,-t/2,t/2 ! GEOMETRY
cyli,,r,-t/2,t/2
vsbv,1,2
 
wpcs,-1,0
wpro,,,90
wpof,,,x_cut
vsbw,all
wpof,,,-2*x_cut
vsbw,all
 
 
vplo
 
et,1,185 ! ATTRIBUTES, MESH
mp,ex,1,E
tb,plastic,1,,,biso
tbdata,,Sy,E2
mp,nuxy,1,nu
vswe,all
 
 
C*******************************************************************
C*** CREATE MPC CONTACT w/PILOT NODE
C*******************************************************************
 
*get,etmax,etype,,num,max
*get,mpmax,mat,,num,max
*get,rmax,real,,num,max
*get,secmax,secp,,num,max
attrmax=max(etmax,max(mpmax,max(secmax,rmax)))
 
 
C*******************************************************************
C*** DEFINE CONTACT ATTRIBUTES
C*******************************************************************
 
et,attrmax+1,174 ! CONTACT ELEMENT TYPE (ON BEAM TIP)
keyo,attrmax+1,4,1 ! FORCE DISTRIBUTED
keyo,attrmax+1,2,2 ! MPC
keyo,attrmax+1,12,5 ! BONDED
 
et,attrmax+2,170 ! TARGET ELEMENT TYPE (PILOT NODE)
keyo,attrmax+2,2,1 ! USER SPECIFIED PILOT NODE CONSTRAINT
keyo,attrmax+2,5,3 ! SHELL-SOLID
 
tshap,pilot ! TARGET SHAPE (PILOT NODE)
 
 
C*******************************************************************
C*** DEFINE REMOTE POINT
C*******************************************************************
real,attrmax+1
type,attrmax+2 ! DEFINE TARGET PILOT ELEMENT (REMOTE POINT)
 
nsel,s,node,,1
cm,pilot_n,node
nd1=1
e,1
 
 
C*******************************************************************
C*** PROMPT USER TO SELECT AREA(S) TO BOND TO PILOT NODE
C*******************************************************************
nsel,s,loc,x,l/2
nsel,u,node,,1
cm,contact_n,node
esln
 
type,attrmax+1 ! OVERLAY BEAM TIP WITH CONTACT ELEMENTS
esurf
 
 
C*******************************************************************
C*** DETERMINE PINBALL
C*******************************************************************
 
cmse,s,contact_n
*get,nnds,node,,count
 
nd=0
pinball=0
*do,i,1,nnds
 cmse,s,contact_n
 nd2=ndnext(nd)
 cmse,a,pilot_n
 pinball=max(pinball,distnd(nd1,nd2))
*enddo
 
r,attrmax+1,,,,,,2*pinball ! PINBALL
 
alls
 
 
C*******************************************************************
C*** APPLIED DISPLACEMENTS
C*******************************************************************
d,1,roty,theta_pilot
nsel,s,loc,x,-l/2
d,all,all
 
 
C*******************************************************************
C*** SOLVE
C*******************************************************************
 
et,11,187 ! TETRAHEDRAL ELEMENT TYPE FOR NLAD-ETCHG
 
*if,k_nlad,eq,1,then
 esel,s,type,,1
 cm,nlad_e,elem
*elseif,k_nlad,eq,2,then
 esel,s,cent,x,-x_cut,x_cut
 cm,nlad_e,elem
*endif
 
fini
 
/solu
 
nladaptive,nlad_e,add,energy,mean,10
nladaptive,nlad_e,on,,,-2,,,11
 
nlge,on
 
alls
save
 
eplo
/sho,png $eplo $/sho,close $/wait,2
 
solve
fini
 
 
C*******************************************************************
C*** POST PROCESS
C*******************************************************************
/post1
/edge,1,1
plns,eppl,x,2
/sho,png $plns,eppl,x,2 $/sho,close $/wait,2
 
--Bill