Electronics

Electronics

Calculating damping force and damping coefficient.

    • dhruvdeshwal17
      Subscriber
      I have modelled an eddy current damper, done its transient analysis. I got the various results , but keen interest is to calculated the damping force and damping coefficient associated with the dampers. Please suggest the procedure to calculated the same.nEddy Current dampers ( Basic Working) - In general ECD consist of a conducting plate and a magnet, which are placed adjacent to each other with a certain gap. A velocity (supposed) is given to the plate and the magnet remains stationary. So, as the plate move, the plate will see a change in a magnetic field by which eddy current will be generated in the plate and due to this current a magnetic field will be generated of opposite polarity as that of the magnet. Due to this generated magnetic field, the magnet experiences a force which is the damping force (In this case). n
    • Navya C
      Ansys Employee

      Hi D_D ,

      Which Ansys tool are you using?

      If you are using Ansys Maxwell, you can calculate the force experienced by the magnet by assigning the force parameter to the magnet.

      You can look at the Below help section to understand how to set up a transient problem.

      If this did not solve your problem, explain How is your simulation setup and what results do you get with the help of some screenshots. This will help interpret the problem correctly.

      Regards,

      Navya

    • dhruvdeshwal17
      Subscriber
      Hi Array
      Im using ANSYS 16.0 APDL
    • Bill Bulat
      Ansys Employee

      If the moving conductive region is continuous in the direction of motion (e.g., a rotating ring or disk), you can do this with a static analysis using the velocity effects feature. Mesh the conductor with SOLID236 and assign the velocity to the nodes of the conductor mesh using BF,ALL,VELO,vx,vy,vz,omegax,omegay,omegaz (specify angular velocity in units of radians/s). If you copy the text I pasted below into a text file and read it into MAPDL with the /INPUT command, you'll have an example:

      fini
      /cle
       
      /pnu,mat,1
      /num,1
       
      /vie,1,1,2,3
       
      /fil,236
      /sys,del 236*.png
       
       
       
      C*********************************************************
      C*** PARAMETERS
      C*********************************************************
      pi=acos(-1)
       
      k_nl=0 ! k_nl=0: LINEAR, k_nl=1: NONLINEAR
       
      key_opt_2=0 ! KEYOPT(2) - 0: TRUE VOLT, 2: TIME INTEGRATED ELEC POT
      key_opt_7=0 ! KEYOPT(7) - 0: ALL NODES, 1: CORNER NODES 
      key_opt_8=0 ! KEYOPT(8) - 0: MAXWELL, 1: LORENTZ
       
      r_PM=0.010 ! PM RADIUS
      r1_cyl=0.012 ! CYLINDER INNER RADIUS
      r2_cyl=0.015 ! CYLINDER OUTER RADIUS
      r_dmn=0.025 ! RADIUS OF SURROUNNDING DOMAIN
      r_gap=0.5*(r_PM+r1_cyl) ! RADIUS OF ARMINT INTERFACE IN AIRGAP
       
      divr_cyl=7 ! # OF DIVISIONS IN RADIAL DIRECT IN CYLINDER
      divz=5 ! # OF ELEMENT DIVISIONS IN AXIAL DIRECTION
       
      l=0.050 ! CYLINDER LENGTH
      l_end=0.025 ! LENGTH OF DOMAIN EXTENDING BEYOND END OF CYLINDER
       
      Hc_PM=1e6 ! PM COERCIVITY
      mur_PM=1.04 ! PM RELATIVE PERMEABILITY
       
      rsv_cyl=3e-8 ! CYLINDER ELECTRIC RESISTIVITY
      mur_cyl=1000 ! CYLINDER RELATIVE PERMEABILITY (USED IF k_nl=0)
       
      RPM=50 !6000 ! ANGULAR VELOCITY, RPM (38 OK, 39 FAILS)
      t_init=1e-9 ! TIME TO ESTABLISH INITIAL FIELD (NOT USED)
      thta=45 ! ROTOR POSITION AT END OF TRANSIENT
      t_final=t_init+(thta/360)/(RPM/60) ! TIME AT END OF TRANSIENT
      nsteps=5 ! # OF TIME STEPS
       
      *if,k_nl,eq,1,then
       /title,SOLID236 V15 VELOCITY EFFECTS, %RPM% RPM, CYL PERMEABILITY NONLINEAR
      *else
       /title,SOLID236 V15 VELOCITY EFFECTS, %RPM% RPM, mur_cyl = %mur_cyl%
      *endif
       
       
      C*********************************************************
      C*** GEOMETRY
      C*********************************************************
      /prep7
       
      asel,none ! PM
      pcir,r_PM,,0,90
      aatt,2,2,200
       
      asel,none ! CYLINDER
      pcirc,r1_cyl,r2_cyl,0,90
      aatt,3,3,200
       
      alls
      cm,keep_a,area
       
      asel,none ! SURROUNDING AIR
      pcirc,0,r_gap,0,90
      pcirc,r_gap,r_dmn,0,90
      cm,scrap_a,area
       
      alls ! BOOLEAN SUBTRACTION
      asba,scrap_a,keep_a,,dele,keep
      cmse,u,keep_a
      aatt,1,1,200
       
      alls
      aplo
       
       
       
      C*********************************************************
      C*** ATTRIBUTES, MESH
      C*********************************************************
      et,1,236 ! AIR
      keyo,1,7,key_opt_7 ! FORCE OUTPUT
      keyo,1,8,key_opt_8 ! FORCE CALCULATION
      mp,murx,1,1
       
      et,2,236 ! PM
      keyo,2,7,key_opt_7 ! FORCE OUTPUT
      keyo,2,8,key_opt_8 ! FORCE CALCULATION
      mp,murx,2,mur_PM
      mp,mgyy,2,Hc_PM
       
      et,3,236,1 ! CYLINDER
      keyo,3,2,key_opt_2 ! TRUE/TIME INTEGRATED VOLT
      keyo,3,7,key_opt_7 ! FORCE OUTPUT
      keyo,3,8,key_opt_8 ! FORCE CALCULATION
      mp,murx,3,mur_cyl
      mp,rsvx,3,rsv_cyl
       
      mp,rsvx,3,rsv_cyl
       
      *if,k_nl,eq,0,then
       mp,murx,3,mur_cyl
      *else
       fifi1=0.94 ! hyperco 50 b-h 0.014in input, STATOR minimum
       tb,bh,3
       tbpt,defi,0,0
       tbpt,defi,2/0.01257,1.5*fifi1
       tbpt,defi,4/0.01257,1.8*fifi1
       tbpt,defi,5/0.01257,1.87*fifi1
       tbpt,defi,6/0.01257,1.93*fifi1
       tbpt,defi,8/0.01257,2.0*fifi1
       tbpt,defi,10/0.01257,2.05*fifi1
       tbpt,defi,20/0.01257,2.15*fifi1
       tbpt,defi,40/0.01257,2.195*fifi1
       tbpt,defi,50/0.01257,2.21*fifi1
       tbpt,defi,60/0.01257,2.225*fifi1
       tbpt,defi,80/0.01257,2.24*fifi1
       tbpt,defi,100/0.01257,2.25*fifi1
       tbpt,defi,150/0.01257,2.28*fifi1
       tbpt,defi,400/0.01257,2.4*fifi1
      *endif
       
      csys,1 ! # OF DIVISIONS THRU CYL THICKNESS
      lsel,s,loc,x,r1_cyl+0.25*(r2_cyl-r1_cyl),r1_cyl+0.75*(r2_cyl-r1_cyl)
      lesi,all,,,divr_cyl,,1
       
      alls ! MESH AREAS
      et,200,200,7
      ames,all
       
      csys,1 ! FULL 360 DEGREE GEOMETRY
      agen,4,all,,,0,90,0
       
      csys,1 ! MERGE NODES/KPS INSIDE ARMINT INTERFACE
      ksel,s,loc,x,0,r_gap
      lslk,s,1
      asll,s,1
      alls,belo,area
      numm,node,1e-8,1e-8
      numm,kp,1e-8,1e-8
       
      csys,1 ! MERGE NODES/KPS OUTSIDE ARMINT INTERFACE
      ksel,s,loc,x,r_gap,r_dmn
      lslk,s,1
      asll,s,1
      alls,belo,area
      numm,node,1e-8,1e-8
      numm,kp,1e-8,1e-8
       
      eplo
       
       
      C********************************************
      C*** EXTRUDE MESHED AREAS INTO MESHED VOLUMES
      C********************************************
      extopt,esize,divz,0
      extopt,aclear,1
      extopt,attr,1,1,1
       
      csys
       
      asel,s,mat,,1
      type,1
      vext,all,,,0,0,l/2
       
      asel,s,mat,,2
      type,2
      vext,all,,,0,0,l/2
       
      asel,s,mat,,3
      type,3
      vext,all,,,0,0,l/2
       
      extopt,attr,0,0,0
       
      vsel,s,mat,,1
      alls,belo,volu
      asel,r,loc,z,l/2
      type,1, $mat,1, $real,1
      vext,all,,,0,0,l_end
       
      vsel,s,mat,,2
      alls,belo,volu
      asel,r,loc,z,l/2
      type,1, $mat,1, $real,1
      vext,all,,,0,0,l_end
       
      vsel,s,mat,,3
      alls,belo,volu
      asel,r,loc,z,l/2
      type,1, $mat,1, $real,1
      vext,all,,,0,0,l_end
       
      alls
      vplo
       
      csys,1 ! MERGE NODES/KPS INSIDE ARMINT INTERFACE
      ksel,s,loc,x,0,r_gap
      lslk,s,1
      asll,s,1
      vsla,s,1
      alls,belo,volu
      numm,node,1e-8,1e-8
      numm,kp,1e-8,1e-8
      cm,PM_v,volu
       
      csys,1 ! MERGE NODES/KPS OUTSIDE ARMINT INTERFACE
      ksel,s,loc,x,r_gap,r_dmn
      lslk,s,1
      asll,s,1
      vsla,s,1
      alls,belo,volu
      numm,node,1e-8,1e-8
      numm,kp,1e-8,1e-8
      cm,cyl_v,volu
       
      alls ! GO AHEAD AND MERGE ALL NODES - USE VELOCITY EFFECTS INSTEAD OF ARMINT
      numm,node,1e-8,1e-8
      numm,kp,1e-8,1e-8
      eplo
       
       
       
      C********************************************
      C*** FLUX PARALLEL EXTERIOR
      C********************************************
      alls
      asel,s,ext
      csys,1
      ksel,s,loc,x,r_gap
      lslk,s,1
      asll,u,1
      !asel,u,loc,z
      da,all,az
       
      vsel,s,mat,,3
      alls,belo,volu
      asel,r,loc,z
      da,all,volt
       
      !alls,belo,volu
      !asel,r,loc,z,l/2
      !cp,1,volt,all
       
       
       
      C********************************************
      C*** APPLY VELOCTY TO ROTOR
      C********************************************
      vsel,s,mat,,3
      alls,belo,volu
      bf,all,velo,,,,,,RPM*2*pi/60 ! RADIANS/s
       
       
      fini
       
       
      C********************************************
      C*** STATIC SOLVE
      C********************************************
      /solu
      alls
      pivc,off
       
      *if,k_nl,gt,0,then
       
      autots,on ! TURN ON AUTO TIME STEPPING
      nsub,5,25,5 ! RANGE OF ALLOWABLE SUBSTEPS
      outr,all,all ! SAVE ALL CALCULATED RESULTS
      lnsr,on ! LINE SEARCH ALGORITHM CAN HELP WITH CONVERGENCE
      kbc,0 ! RAMP APPLIED LOADS
       
      *endif
       
      save
      solv
      fini
       
       
       
      C********************************************
      C*** POST PROCESS
      C********************************************
      /post1
       
       
      esel,s,mat,,3 ! CYLINDER MECHANICAL POWER (TORQUE TIMES OMEGA)
      nsle
      esln
      emft
      P_mech_cyl = 2*(2*pi*RPM/60)*_tzsum
       
       
      esel,s,mat,,2 ! PM MECHANICAL POWER (TORQUE TIMES OMEGA)
      nsle
      esln
      emft
      P_mech_PM = 2*(2*pi*RPM/60)*_tzsum
       
       
      vsel,s,mat,,3 ! DETERMINE HEAT PRODUCED IN CYLINDER
      alls,belo,volu
      set,last
      etab,,jhea
      etab,,volu
      smult,ht,jhea,volu
      ssum
      *get,ht_total,ssum,,item,ht
      ht_total=2*ht_total
       
       
      /ann,dele
      /tla,-0.25,0.90,Net Heat in Cylinder: %ht_total% W
      /tla,-0.25,0.85,Cylinder Mechanical Power: %P_mech_cyl% W
      /tla,-0.25,0.80,PM Mechanical Power: %P_mech_PM% W
       
       
      plve,b,,,,vect,,on
      /sho,png $plve,b,,,,vect,,on $/sho,close $/wait,2
       
      plve,jt,,,,vect,,on
      /sho,png $plve,jt,,,,vect,,on $/sho,close $/wait,2
       
      rsys,1
      plns,b,y
      /sho,png $plns,b,y $/sho,close $/wait,2
       
      plet,jhea,1
      /sho,png $plet,jhea,1 $/sho,close $/wait,2
       
       
      /eof

       

       

      -- Bill

Viewing 3 reply threads
  • You must be logged in to reply to this topic.