General Mechanical

General Mechanical

CONC in material

    • Gina Dokke
      Subscriber

      I looking for change in RH in wood and then should I change Bondary Condition and Initial Condition. I have design 1/4 of the piece of wood and use the symetric to get the whole dimensional. 
      When I do the analysis I get a Concetration at the beginning that is wrong. I define D to be the final EMC (Equlibrium moisture content). This is defined at the outside (the circular part). I define the IC (inital condition) to be initial EMC and this on the whole piece. The initial EMC is higher than final EMC. When I do the simulation will I get a result that the concentration at the beginning is wrong. What should I do to get a better result in the beginning? 

      After a time will I get a better result. This result have correct result near the center of circel (the red area) who is the initial EMC and the blue area who is the same as the final EMC. 

      What should I do to get a better result in the beginning or what do it wrong in the beginning? 

       

    • Bill Bulat
      Ansys Employee

      Hi Gina,

      I'm sorry but it is not perfectly clear to me what issue you are facing. It sounds like you are trying to make the initial concentration (presumably of moisture) in the wood higher than that of the surrounding air, and you expect a gradual reduction in moisture as it diffuses into the surrounding air. This is of course to be expected. But it sounds like you find that at the beginning of the transient, the calcuklated concentration in the wood is lower than that of the surrouding air, which is physically impossible. I created a small test case to try to duplicate your observation (please see the listing at the end of this reply which you can copy into a file and read into MAPDL with the /INPUT command). My test case seems to work fine... I am so far unable to reproduce the problem. However, I have seen similar non-physical calculated results before.What I saw happens in thermal conduction transient analyses too. Sometimes called thermal undershoot or spurious oscillations, the calculated concentration (or temperature) is seen to oscillate - exhibit 2nd order system behavior. Thermal and diffusion systems are first order and do not physically respond in this way. The calculated oscillations are often caused by suddenly changing boundary conditions and/or very small time steps. Applying loads more gradually and/or using larger initial time steps can help alleviate this. Also, it sometimes helps to use a diagonalized diffusion damping matrix (set KEYOPT(1)=1 on the ET command) or create a mesh without midside nodes (use the MSHMID,2 command prior to creating the mesh so that the elements are linear rather than quadratic). I should say, though, that I've never seen a case of this that is as severe as what your first image implies, so I'm not sure if my suggestions will help or if they are even relevant. Hopefully my small test case (below) will help.

      Kind regards,

      Bill

       

       

       

      finish
      /clear
       
      /pnu,mat,1
      /num,1
       
      /sys,del file*.png
       
       
      C************************************************
      C*** PARAMETERS
      C************************************************
      w=3.5*0.0254 ! WOOD WIDTH (m)
      h=1.5*0.0254 ! WOOD HEIGHT (m)
      r=1.50*w/2 ! RADIUS OF ENCLOSING AIR (m)
      d_wood=2e-8 ! MOISTURE DIFFUSIVITY IN WOOD (m^2/s)
      d_air=2.56e-5 ! MOISTURE DIFFUSIVITY IN AIR (m^2/s)
      conc_ic=0.010 ! INITIAL MOISTURE CONCENTRATION OF WOOD (kg/m^3)
      conc_env=0.001 ! MOISTURE CONCENTRATION OF SURROUNDING AIR (kg/m^3)
      esz=0.1*h/2 ! MESH SIZE (m)
      t_final=10*3600 ! FINAL TIME (s)
       
       
      C************************************************
      C*** MODEL
      C************************************************
      /prep7
      rect,,w/2,,h/2 ! GEOMETRY
      aatt,1,1,1
      pcirc,,r,0,90
      asba,2,1,,dele,keep
      asel,u,area,,1
      aatt,2,2,2
       
      et,1,238 ! WOOD ATTRIBUTES
      mp,dxx,1,d_wood
       
      et,2,238 ! AIR ATTRIBUTES
      mp,dxx,2,d_air
       
      esiz,esz ! MESH
      alls
      ames,all
       
       
      C************************************************
      C*** BCs & ICs
      C************************************************
      csys,1
      nsel,s,loc,x,r
      d,all,conc,conc_env
       
      esel,s,mat,,2
      nsle
      ic,all,conc,conc_env
       
      esel,s,mat,,1
      nsle
      ic,all,conc,conc_ic
       
      fini
       
       
      C************************************************
      C*** SOLVE
      C************************************************
      /solu
      anty,trans
      time,t_final
      nsub,25,50,25
      outr,all,all
      alls
      save
      solv
      fini
       
       
      C************************************************
      C*** POST PROCESS
      C************************************************
      /post26
       
      nsol,2,node(0,0,0),conc
       
      /axl,x,Time (s)
      /axl,y,CONC @ CENTER OF WOOD (kg/m^3)
      plva,2
      /sho,png $plva,2 $/sho,close $/wait,2
      fini
       
       
      /post1
       
      set,first
      plns,conc
      /sho,png $plns,conc $/sho,close $/wait,2
       
      set,last
      plns,conc
      /sho,png $plns,conc $/sho,close $/wait,2

       

Viewing 1 reply thread
  • You must be logged in to reply to this topic.