General Mechanical

General Mechanical

DAMORPH failure – II

    • verners
      Subscriber

      Hello,

      further comments on this post

      https://forum.ansys.com/forums/topic/damorph-failure/

      would be appreciated (a new comment was added).

    • Bill Bulat
      Ansys Employee

      I probably haven't used this command for over twenty years. It's hard to figure out how to use it effectively. As I recall, it is used in conjunction with the now undocumented PHYSICS command. Although undocumented, the PHYSICS command still works at 2022R1 (the most recent release I have tested). DAMORPH is probably not a good way to go if your objective is to simulate pull-in of a capacitively induced MEMS device (e.g., RF switch). For that, I would use coupled field PLANE223 with keyopt(1)=1001 and surface-to-surface contact elements with CNOF (contact normal offset) real constant to prevent complete closure of gaps (which would cause an element formulation error).

      If you copy the following APDL into an input file and read that input file into MAPDL, you should have a working example of DAMORPH. Electrostatic and structural analyses are done sequentially (load vector coupling via LDREAD). The electrostatic mesh is then morphed via DAMORPH. A second sequence of electrostatic-then-structural calculations is made with the morphed mesh, and the electrostatic mesh is morphed again.

       

       

      fini
      /cle
      /pnu,mat,1
      /num,1
      /sys,del *.ph
      /sys,del *.png
       
       
      C********************************************
      C*** PARAMETERS (MKS)
      C********************************************
      l=0.00075 ! DOMAIN LENGTH
      h=0.0002 ! DOMAIN HEIGHT
      l_elctrd=0.0005 ! ELECTRODE (BEAM) LENGTH
      t_elctrd=0.000005 ! ELECTRODE THICKNESS
      gap0=0.00003 ! INITIAL GAP UNDER ELECTRODE
      E_elctrd=2e10 ! ELECTRODE ELASTIC MODULUS
      V_elctrd=150 ! ELECTRODE VOLTAGE
       
      esz1=gap0/2 ! MESH SIZE

       

       
       
      C********************************************
      C*** GEOMETRY
      C********************************************
      /prep7
       
      asel,none
      rect,,l,,h
      cm,scrap_a,area
       
      asel,none
      rect,,l_elctrd,gap0,gap0+t_elctrd
      aatt,1,,1
      cm,elctrd_a,area
       
      alls
      cmse,all
      asba,scrap_a,elctrd_a,,dele,keep
      cmse,u,elctrd_a
      aatt,2,,2
      cm,air_a,area
       
       
      C********************************************
      C*** ATTRIBUTES, MESH
      C********************************************
      et,1,183,1
      mp,ex,1,E_elctrd
       
      et,2,121
      mp,perx,2,1
       
      msha,1
      alls
      esiz,esz1
      ames,all
       
       
       
      C********************************************
      C*** BCs
      C********************************************
      esel,s,mat,,1
      nsle
      esel,s,mat,,2
      nsle,r
      cm,V_elctrd_n,node
       
      nsle
      nsel,r,loc,x
      cm,d_elctrd_n,node
       
      nsel,s,loc,y
      d,all,volt
      alls
      cmse,all
      d,d_elctrd_n,ux
      d,d_elctrd_n,uy
      d,V_elctrd_n,volt,V_elctrd
       
      esel,s,mat,,2
      cmse,s,V_elctrd_n
      sf,all,mxwf
       
       
      C********************************************
      C*** PHYSICS ENVIRONMENTS
      C********************************************
      alls
      save,both,db
       
      et,1,0
      nlge,off
      physics,write,es,es,ph
       
      resu,both,db
       
      alls
      sfede,all,all,mxwf
      et,2,0
      nlge,on
      physics,write,struct,struct,ph
       
      fini
       
       
      C********************************************
      C*** SOLVE
      C********************************************
      /solu
       
      physics,clear ! ELECTROSTATIC SOLVE
      physics,read,es,es,ph
      solv
      fini
      /post1
      plns,volt 
      /sho,png $plns,volt $/sho,close $/wait,2
      fini
       
      /solu
       
      physics,clear ! STRUCTURAL SOLVE
      physics,read,struct,struct,ph
      asel,s,mat,,1
      alls,belo,area
      ldread,forc,,,,,file,rth
      solv
      fini
      /post1
      plns,u,y,2
      /sho,png $plns,u,y,2 $/sho,close $/wait,2
      fini
       
       
      C********************************************
      C*** MORPH ELECTROSTATIC MESH
      C********************************************
      /prep7
      alls
      !physics,clear
      !physics,read,es,es,ph
      ddel,all,all
      sfed,all,all,mxwf
      et,2,121
      asel,s,mat,,2
      damorph,air_a !,,1
      /edg,1,0
      eplo
      /sho,png $eplo $/sho,close $/wait,2
      fini
       
       
      C********************************************
      C*** SECOND SOLVE WITH MORPHED MESH
      C********************************************
      /solu
       
      physics,clear ! ELECTROSTATIC SOLVE
      physics,read,es,es,ph
      solv
      fini
      /post1
      plns,volt
      /sho,png $plns,volt $/sho,close $/wait,2
      fini
       
      /solu
       
      physics,clear ! STRUCTURAL SOLVE
      physics,read,struct,struct,ph
      asel,s,mat,,1
      alls,belo,area
      ldread,forc,,,,,file,rth
      solv
      fini
      /post1
      plns,u,y,2
      /sho,png $plns,u,y,2 $/sho,close $/wait,2
      fini
       
       
      C********************************************
      C*** SECOND MORPHING ELECTROSTATIC MESH
      C********************************************
      /prep7
      alls
      !physics,clear
      !physics,read,es,es,ph
      ddel,all,all
      sfed,all,all,mxwf
      et,2,121
      asel,s,mat,,2
      damorph,air_a !,,1
      /edg,1,0
      eplo
      /sho,png $eplo $/sho,close $/wait,2
      fini
       
       
      /eof
       
       
      Regards,
       
      Bill
    • verners
      Subscriber

      Hello,

      thank you for the script. Additionally I would like to ask if the PHYSICS command is a prerequisite for using DAMORPH correctly.
      Best regards,

      Osvalds

    • verners
      Subscriber

      PS: apparently the critical detail that was missing in my earlier script was shared lines between the structural and non-structural regions

Viewing 3 reply threads
  • You must be logged in to reply to this topic.