General Mechanical

General Mechanical

HOW TO COMBINE SPECTRAL AND STATIC ANALYSIS MECHANICAL APDL.

    • vgiordano3
      Subscriber

      Hi everyone,

      I'm conducting a vibrational analysis simulation. In the real case, the structure is loaded with 176 pounds of weight and excited with a PSD spectrum. I've done the spectral analysis (SPER) after the mode extraction and then combined the modes. Then I've done the static analysis. How can I combine the results given by the modal cqc combination and the static analysis to obtain the complessive stress of the structure? I tried using the following commands:

       

      !MODEL

      ...

      !Static Analysis

      /solu

      antype,static

      ...

      /post1
      lcdef,1

      !Modal and spectral analysis

      ...

      /post1 
      lcfile,2,file,mcom     !file.mcom stores the cqc results
      lcoper,add,1
      lcoper,add,2

      This way didn't work.

      Thank you in advance!

       

    • Chandra Sekaran
      Ansys Employee

      you cannot use 'lcfile,2,file,mcom'. file.mcom is not a load case file. It has APDL command instructions to combine various modes. 

      a) The SPRS results are obtained by squaring mode shapes and taking square root. So all the signs are lost. So you may want to do SRSS of static and SPRS results.Refer to https://ansyshelp.ansys.com/account/secured?returnurl=/Views/Secured/corp/v222/en/ans_bas/Hlp_G_BAS5_4.html?q=lcoper for documentation on load case operations

      b) below is a version to simply add static and sprs results. You will need to modify this to do the SRSS.

      /post1

      /input,file,mcom    ! combine modes to get sprs results

      lcwrite,2  ! write the combined results as load case 2

      file,....   ! point to the static results file

      set,last  ! read the last set of static results

      lcoper,add,2   ! add the results in database with load case 2

       

    • vgiordano3
      Subscriber

      Hi Chandra, thanks for your answer. Can you be more specific on how to do SRSS of static and SPRS results? My case is the following:

      I tried doing Static analysis and SPRS analysis separately and the sum of the two case is less than the static case only. I guess the problem is in the fact that signs are lost. Thank you in advance! 

       

      fini
      /clear

      !
      !DIMENSIONS
      h=0.76            
      l=1.41            
      w=0.8            
      ws=0.003        
      wcer=0.020        
      lc1=0.30575       
      lc2=1.1065        
      lcc1=0.32575       
      lcc2=1.0865        
      hc1=0.18075-0.05        
      hcc1=0.20075-0.05    
      hc2=0.67925-0.05        
      hcc2=0.65925-0.05   
      wc1=0.16575        
      wc2=0.66425        
      tc=1.5e-3        
      h1=0.515        
      h2=0.415        
      w1=0.29       
      w2=0.49      
      w3=0.54        

      ls1=0.273       
      ls2=1.137        
      hs1=0.622-0.05       
      hs2=0.522-0.05       



      lunghezzacer=0.135
      lcera1=lc1+0.1
      lcera2=lcera1+0.1
      lcerb2=lc2-0.1
      lcerb1=lcerb2-0.1
      lcerc1=lc1+0.040
      lcerc2=lcerc1+lunghezzacer
      lcerd1=lc1+((lc2-lc1)/2)-(lunghezzacer/2)
      lcerd2=lcerd1+lunghezzacer
      lcere2=lc2-0.040
      lcere1=lcere2-0.135

      hcer2=hcc2-0.01
      hcer1=hcc1+0.01


      lcop1=lcc1+0.01
      lcop2=lcc2-0.01
      hcop1=hcc1+0.01
      hcop2=hcc2-0.01


      wh1=40e-3                
      th1=4e-3

      !UPN160
      wu1=65e-3
      wu2=160e-3
      tu1=10.5e-3
      tu2=7.5e-3


      E=210e+9    !Modulo di young acciaio
      ni=0.3    !Coefficiente di Poisson acciaio 
              !e AISI304
      rho=7850    !Densità acciaio
      E1=196e+9    !Modulo di young AISI304
      rho1=7910    !Densità AISI304

      rho2=3500    !Densità ABS
      E2=70e+6    !Modulo di young ABS
      ni2=0.37    !Coefficiente di Poisson ABS

      /prep7
      !Spigoli telaio
      k,1 $ k,2,l $ k,3,l,,w $ k,4,,,w
      k,5,,h $ k,6,l,h $ k,7,l,h,w $ k,8,,h,w
      k,9,,h1 $ k,10,l,h1 $ k,11,,h,w1 $ k,12,l,h,w1
      k,13,,h,w2 $ k,14,l,h,w2 $ k,15,,h,w3
      k,16,l,h,w3 $ k,17,,h2

      !keypoint fissaggio staffe-upn160
      k,46,lc1,h1 $ k,47,lc2,h1 
      k,48,lc1,hs1 $ k,49,lc1,hs2
      k,50,lc2,hs1 $ k,51,lc2,hs2
      k,52,lc1,h1,w1 $ k,53,lc1,h1,w3
      k,54,lc2,h1,w1 $ k,55,lc2,h1,w3

      !Spigoli cassetta
      k,18,lc1,hc1,wc1 $ k,19,lc2,hc1,wc1
      k,20,lc2,hc1,wc2 $ k,21,lc1,hc1,wc2
      k,22,lc1,hc2,wc1 $ k,23,lc2,hc2,wc1
      k,24,lc2,hc2,wc2 $ k,25,lc1,hc2,wc2

      !Spigoli staffe
      k,27,lc1,h,w1 $ k,28,lc1,hs1,w1 $ k,29,lc1,hs2,w1

      k,31,lc1,h,w3 $ k,32,lc1,hs1,w3 $ k,33,lc1,hs2,w3

      k,35,lc2,h,w1 $ k,36,lc2,hs1,w1 $ k,37,lc2,hs2,w1

      k,39,lc2,h,w3 $ k,40,lc2,hs1,w3 $ k,41,lc2,hs2,w3

      k,42,lcc1,hcc2,wc2 $ k,43,lcc1,hcc1,wc2

      k,44,lcc2,hcc2,wc2 $ k,45,lcc2,hcc1,wc2

      !KEYPOINT CERNIERE/CHIUSURE
      k,56,lcera1,hcc2,wc2 $ k,57,lcera2,hcc2,wc2
      k,58,lcera2,hcer2,wc2 $ k,59,lcera1,hcer2,wc2

      k,60,lcerb1,hcc2,wc2 $ k,61,lcerb2,hcc2,wc2
      k,62,lcerb2,hcer2,wc2 $ k,63,lcerb1,hcer2,wc2

      k,64,lcerc1,hcer1,wc2 $ k,65,lcerc2,hcer1,wc2
      k,66,lcerc2,hcc1,wc2 $ k,67,lcerc1,hcc1,wc2

      k,68,lcerd1,hcer1,wc2 $ k,69,lcerd2,hcer1,wc2
      k,70,lcerd2,hcc1,wc2 $ k,71,lcerd1,hcc1,wc2

      k,72,lcere1,hcer1,wc2 $ k,73,lcere2,hcer1,wc2
      k,74,lcere2,hcc1,wc2 $ k,75,lcere1,hcc1,wc2

      !KEYPOINT COPERCHIO
      k,76,lcop1,hcop2,wc2 $ k,77,lcop2,hcop2,wc2
      k,78,lcop2,hcop1,wc2 $ k,79,lcop1,hcop1,wc2
      !Rinforzo coperchio
      k,80,lcop1,hcop2,wc2-0.01 $ k,81,lcop2,hcop2,wc2-0.01
      k,82,lcop2,hcop1,wc2-0.01 $ k,83,lcop1,hcop1,wc2-0.01

      !KEYPOINT RINFORZO STAFFE
      k,84,lc1-0.03,hs1 $ k,85,lc1-0.03,hs1,w3
      k,86,lc2+0.03,hs1,w3 $ k,87,lc2+0.03,hs1

      !Ritti
      l,1,17 $ l,17,9 $ l,9,5 $ l,2,10 
      l,10,6 $ l,3,7 $ l,4,8

      !Traversi e longheroni
      l,1,2 $ l,2,3 $ l,3,4 $ l,4,1
      l,5,6 $ l,6,12 $ l,12,14 $ l,14,16 $ l,16,7
      l,7,8 $ l,8,15 $ l,15,13 $ l,13,11 $ l,11,5
      l,11,12 $ l,13,14 $ l,15,16

      !Montante
      l,9,46 $ l,46,47 $ l,47,10

      !Traverse oblique
      l,17,2 $ l,1,8 $ l,6,3

      !Aree relative alla cassetta
      a,18,22,28,29    !A1
      a,22,25,32,28    !A2
      a,28,32,33,29      !A3
      a,21,33,32,25    !A4
      a,18,29,33,21      !A5
      a,18,22,23,19    !A6
      a,18,19,20,21      !A7
      a,22,23,24,25    !A8
      a,19,37,36,23      !A9
      a,23,36,40,24    !A10
      a,36,37,41,40      !A11
      a,20,24,40,41    !A12
      a,19,20,41,37    !A13

      !Aree rinforzi cassetta
      a,25,42,43,21                !A14
      a,25,24,44,61,60,57,56,42        !A15
      a,24,20,45,44                !A16
      a,20,21,43,67,66,71,70,75,74,45        !A17

      !Aree staffe orizzontali
      a,48,28,52,46    !A18
      a,46,52,29,49    !A19
      a,28,32,53,52    !A20
      a,52,53,33,29    !A21
      a,36,50,47,54    !A22
      a,47,51,37,54    !A23
      a,36,40,55,54    !A24
      a,54,55,41,37    !A25

      !Aree cerinere
      a,56,57,58,59    !A26 
      a,60,61,62,63    !A27
      a,64,65,66,67    !A28
      a,68,69,70,71    !A29
      a,72,73,74,75    !A30

      !Area coperchio
      a,76,59,58,63,62,77,78,73,72,69,68,65,64,79    !A31
      !Aree rinforzo coperchio
      a,76,59,58,63,62,77,81,80            !A32
      a,77,81,82,78                    !A33
      a,82,83,79,64,65,68,69,72,73,78            !A34
      a,76,79,83,80                    !A35

      !Aree rinforzo staffe
      a,48,28,32,85,84                !A36
      a,50,36,40,86,87                !A37

      !Tipologia elementi,materiali e sezioni
      et,1,beam188,,,3                !Beam 188 con f.f. cubica
      sectype,1,beam,hrec,tubquad        !Sezione tubolare quad
      secdata,wh1,wh1,th1,th1,th1,th1    !Dati sezione tubolare quad

      sectype,2,beam,chan,upn160        !Sezione upn160
      secdata,wu1,wu1,wu2,tu1,tu1,tu2    !Dati sezione upn 160

      et,2,shell63                !Shell163
      !Definizione del materiale 1 Acciaio strutturale
      mp,ex,1,E                !Modulo Young material 1
      mp,nuxy,1,ni                !Coeff poisson material 1
      mp,dens,1,rho                !Densità material 1
      !Definizione materiale 2 Acciaio inox
      mp,ex,2,E1                !Modulo Young material 2
      mp,nuxy,2,ni                !Coeff Poisson material 2
      mp,dens,2,rho1                !Densità material 2
      !Definizione materiale 3 ABS
      mp,ex,3,E2                !Modulo di Young material 3 ABS
      mp,nuxy,3,ni2                !Coeff di Poisson material 3 ABS
      mp,dens,3,rho2                !Densità ABS

                          !Spessore dello shell cassetta

      r,2,ws                    !Spessore dello Shell delle staffe

      r,3,wcer                !Spessore cerniere

       


      !Meshing

      !Mesh telaio
      esize,0.05
      lsel,r,line,,1,24
      latt,1,,1,,,,1    
      lmesh,all
      lsel,all

      esize,0.05
      lsel,r,line,,28,30
      latt,1,,1,,,,1    
      lmesh,all
      lsel,all

      lsel,r,line,,25,27
      k,1000,,+1e+12
      latt,1,,1,,1000,,2
      lmesh,all
      lsel,all

      !Mesh cassetta
      asel,r,area,,1,17
      type,2
      r,1,tc
      mat,2
      allsel,all

      asel,r,area,,31,35
      type,2
      r,1,tc
      mat,2
      allsel,all

      !Mesh staffe
      asel,r,area,,18,25
      type,2
      r,2,ws
      mat,2
      allsel,all

      asel,r,area,,36,37
      type,2
      mat,2
      r,2,ws
      allsel,all

      !Mesh chiusure
      asel,r,area,,26,27
      type,2
      mat,3
      r,3,wcer
      allsel,all

      !Mesh cerniere in acciaio
      asel,r,area,,28,30
      type,2
      mat,2
      r,3,wcer
      allsel,all
      esize,0.02
      amesh,all

      /eshape,1,1
      eplo

      !vincoli
      ksel,r,kp,,1,4,1
      nslk,r,n,all
      d,all,all
      allsel,all

      !ANALISI STATICA
      !Definzione carico statico
      asel,r,area,,7
      sfa,all,,pres,2000
      sbctran
      allsel,all

      /solu
      antype,static
      allsel,all
      outres,all,all
      outpr,all,all
      save
      solve
      finish

      /post1
      set,last
      reswrite,static
      file,static,rst


      !ANALISI MODALE

      /solu
      antype,modal,new
      modopt,lanb,all,10,500
      !mxpand,,,,yes,,,
      allsel,all
      outres,all,all
      outpr,all,all
      solve
      finish

      /solu
      antype,spectrum,new
      spopt,sprs,,yes
      svtyp,2
      sed,0.0,1.0,0.0
      ! DEFINIZIONE SPETTRO DI RISPOSTA DELLA STRUTTURA
      freq,10,24.9,40,49.9,74.9
      freq,124.9,149.9,174.9,199.9,249.9
      freq,274.9,299.9,324.9,349.9,374.9
      freq,399.9,424.9,449.9,474.9,499.9
      sv,,6.1025,6.1025,6.1025,4.9883,3.4447
      sv,,2.1612,1.8300,1.5899,1.4076,1.1484
      sv,,1.0528,0.9725,0.9040,0.8450,0.7934
      sv,,0.7481,0.7079,0.6719,0.6396,0.6104
      ! FINE DEFINIZIONE SPETTRO DI RISPOSTA
      dmprat,0.00001        ! Coefficiente di smorzamento
      allsel,all
      outres,all,all
      outpr,all,all
      solve
      finish

      /solu
      antype,modal,new
      modopt,lanb,all,10,500
      mxpand,,,,yes,,,
      allsel,all
      outpr,all,all
      outres,all,all
      solve
      finish

      ! COMBINAZIONE QUADRATICA DEI MODI

      /solu
      antype,spectrum,new
      cqc,0.001,disp
      allsel,all
      outpr,all,all
      outres,all,all
      solve
      finish

       

      /post1    
      /input,file,mcom 
      lcwrite,2
      file,static,rst
      set,last
      lcoper,add,2

       

       

Viewing 2 reply threads
  • You must be logged in to reply to this topic.