Learning Forum

[Rana Nasser]

Hi everyone,

In the attached file below I need to simulate the sub grade reaction of the soil rested on the wall in the 3 directions. I have used the Elastic support to do this, but it let me only input the stiffness in one direction -perpendicular to the selected surface- and I didn't fined any option to change this in the elastic support sittings, so how could I do this?

Thanks all!

[peteroznewman]

Hi Rana,

Your model has a problem. The wall is moving away from the soil because the acceleration was applied to the base of the wall and has a net displacement away from the soil and there is no acceleration acting on the soil.

Please zip up the C:Elayat ansys modelseismic2 file and attach it so I can look at the acceleration-time history.

Regards,

Peter

[Sandeep Medikonda]

Rana,

  You can specify normal and tangential stiffness using a command snippet. you might find this article useful.

~Sandeep

[Rana Nasser]

Thanks Peter and Sandeep for your response!

 

Peter you are right I noticed this mistake and fixed it after attaching the file, the corrected file and the seismic input file is attached below.

**I don't know what is the problem ,but I can't upload the archived file again in this reply 

[Rana Nasser]

Thanks so much sandeep for this useful article, but now I have 3 questions about contact elements!

1- what is the pinball radius? what is it represents in the reality?

2- For the vertical contact element in this model ( which attached above in the post), this contact is element connecting between a concrete wall and a soil strip and the model is subjected to an acceleration time history as a base excitation in x direction. Should I use the element type of this contact element as compine39 or the conta174 and targe170 elements will be enough?

3- When I opened this model in mechanical APDL there was a surface154 element type defined, Is this element is used for the ordinary elastic support?

Thank you so much again for shearing knowledge!!  

[Rana Nasser]

There is one more question!!

In the article that you attached above sandeep the author said that the this technique can be used for linear tests, but in my model this face will be subjected to an acceleration time history base excitation with a peak ground acceleration= 1.47 m/sec^2 =0.15g. This excitation may lead to large displacement in the soil body, so how can I overcome this?! 

[Sandeep Medikonda]

Rana, you can read about the pinball radius here.

With regards to your other questions. I am unable to open your model but by default, Mechanical writes out SURF154 elements. So in that snippet, you are deselecting these elements and overwriting with contact elements. 

I haven't tried this method but I would recommend you to start with a bonded contact. See if it runs, keep an eye on the solver output for warning/error messages. Then try the element type that interests you. Let us know your findings and hopefully, this will give us more insight.

Regards,

Sandeep

[Rana Nasser]

Hi,

Excuse me for my very tiny experience in APDL commands. I have read the command and I think I'm understanding each row from the article, but I can't determine where should I input the value of ARG1, ARG2, ARG3 and which row is the star of the command? 

!   Commands inserted into this file will be executed just prior to the ANSYS SOLVE command.
!   These commands may supersede command settings set by Workbench.

 

!   Active UNIT system in Workbench when this object was created:  Metric (mm, t, N, s, mV, mA)

! Generate an elastic foundation in normal and both tangent directions
! on Named Selection "Elastic_Here", a set of nodes on face(s).
!
! These commands have been tested on a 3D solid model only.
!
! ARG1 is the NORMAL stiffness (Force per Unit Length per Unit Area)
! ARG2 is TANGENTIAL stiffness (Force per Unit Length per Unit Area)
! ARG3 is Pinball Radius, in solver units

! ARG1 & ARG2 must be in the solver units!
! If ARG2 is blank or zero, it is set to ARG1
! ARG1 must be non-zero.
! If ARG3 is zero, then zero will be used, which should activate default
!
*if,ARG1,LE,0,then
   *MSG,ERROR
   ARG1 for Normal Stiffness on XYZ Elastic Foundation must be positive
   /EOF
   *return,-1
*endif
!
*if,ARG2,LE,0,then
   ARG2=ARG1
   /COM,######## ARG2 was made equal to ARG1 ########
*endif
fini
!
/prep7
!
*get,nodemax,NODE,,NUM,MAX        ! highest node number in model
!
cmsel,s,Elastic_Here              ! nodes of the component "Elastic_Here"
esln                              ! select contacting elements
!
! undselect surface effect, contact, MPC and beam elements
esel,u,ename,,151,154
esel,u,ename,,169,180
esel,u,ename,,188,189
*get,maxtype,ETYP,,NUM,MAX        ! highest element type 
*get, maxmat,MAT,,NUM,MAX         ! highest material type 
*get,maxreal,RCON,,NUM,MAX        ! highest real constant
! Set maxtype, maxmat and maxreal to the highest value of all three
*if,maxtype,gt,maxmat,then
   maxmat=maxtype
*else
   maxtype=maxmat
*endif
*if,maxreal,gt,maxtype,then
   maxtype=maxreal
   maxmat=maxreal
*else
   maxreal=maxtype
*endif
! Create required element types and real constant
ET,maxtype+1,CONTA174,,1,,0,3  ! Pure Penalty contact algorithm (stiffness)
KEYOPT,maxtype+1,9,1           ! Exclude initial geometrical penetration or gap and offset
KEYOPT,maxtype+1,12,5          ! Bonded Always
ET,maxtype+2,TARGE170,,1       ! Constraints by user
R,maxreal+1,0,0,-ARG1,,,-abs(ARG3)  ! FKN Absolute Number, ARG3=Absolute Pinball Radius
RMODIF,maxreal+1,12,-ARG2      ! FKT as Absolute Number
!
TYPE,maxtype+1                 ! CONTA174 elements
REAL,maxreal+1
MAT,maxmat+1
ESURF                          ! Mesh CONTA174 over underlying element faces
!
*get,current_nodemin,node,,num,min
!
esln,r,1                       ! Select only these CONTA174 elements
esel,r,ename,,174              ! Ensure no other elements
esel,r,real,,maxreal+1
!
! Make a copy of the currently selected nodes
NGEN,2,(nodemax-current_nodemin)+1,ALL,,,0,0,0    ! Copy of nodes at same location
EGEN,2,(nodemax-current_nodemin)+1,ALL,,,0,1,0    ! Copy elements, increment TYPE by 1
!
esel,r,type,,maxtype+2         ! Select these new TARGE170 elements
ENSYM,0,,0,ALL                 ! Reverse TARGE170 elements to face contacts
nsle                           ! Select nodes on these target elements
d,all,all                      ! Constrain all nodes on target elements
!
allsel
! Continue with the analysis
fini
/solu
!

[Sandeep Medikonda]

Rana,

So ARG1, ARG2 and ARG3 are like variables you specify at the start. These have comments at the start, I quickly tested this for a simple case and it works, note that you would have to create a named selected 'Elastic_Here' as well for the support faces.

~Sandeep

[Rana Nasser]

Thank you soooo much Sandeep for this great help, thanks for your time and effort too!!

I'll shear my findings here immediately after running the model and checking the results.

[Sandeep Medikonda]

Sure Rana, Another quick note. I've also, tested this for a non-linear contact (frictional) with Large Deflection turned on and it works without any problems there as well. So, hopefully, this should work in your case as well.

[Rana Nasser]

The command works well in my model too! It caused a good enhancement in the results.  

Thanks so much Sandeep,

Thanks so much Peter.

 

[sdebode]

Hi all,nI have a question regarding the elastic foundation. The page (https://simutechgroup.com/a-normal-and-tangential-elastic-foundation-in-ansys-workbench-mechanical/) its said that the elastic foundation acts as stiffness per unit area. However, when I apply the elastic foundation on an area, and refine the mesh, the stiffness seems to change. I am doing a case of a membrane in shear, so I am applying a in plane shear load to a flat membrane, and the elastic foundation stiffness acts normal on the surface of the membrane. I use Shell281 elements for the membrane mesh, and I use the exact code of the simutech page. See the illustration below.nn I firstly perform a static analysis with the horizontal displacement based load, and then a buckling analysis to find the buckling modes as a consequence of this deformation. The following results show the same buckling mode for one mesh, and a mesh with a element size twice as small.nWhat is the cause of this difference? Is the elastic foundation really applying stiffness per unit area, or is it mesh dependent? Am I missing something.nnThanks in advance for your reply.nnBest regardsnnn