General Mechanical

General Mechanical

NO MODE SELECTED FOR COMBINATION – PSD ANALYSIS

Tagged: 

    • vgiordano3
      Subscriber

      Hello everyone. I'm having some difficulties performing a PSD analysis in Ansys APDL. I have a steel structure and a steel box, joined toghether with 4 brackets. This structure performed a vibrational test according to the MIL-STD-810. The PSD spectrum is the following (blue one) with 176lbs of weight on the box. After I perform the PSD analysis, I have to combine the extracted modes, but the software tells me that no mode were combined, because the partecipation factor must be calculated firts, but I used the command "pfact,1,base" on the code. Can someone help me?

      !Aree rinforzi cassetta
      a,25,42,43,21        !A14
      a,24,25,42,56,57,60,61,44    !A15
      a,24,44,45,20        !A16
      a,20,21,43,67,66,71,70,75,74,45    !A17
       
      !Aree cerinere
      a,56,57,58,59  !A18 
      a,60,61,62,63  !A19
      a,64,65,66,67  !A20
      a,68,69,70,71  !A21
      a,72,73,74,75  !A22
       
      !Area coperchio
      a,76,59,58,63,62,77,78,73,72,69,68,65,64,79  !A23
      !Aree rinforzo coperchio
      a,76,59,58,63,62,77,81,80      !A24
      a,77,81,82,78          !A25
      a,82,83,79,64,65,68,69,72,73,78      !A26
      a,76,79,83,80          !A27
       
      !Tipologia elementi,materiali e sezioni
      et,1,beam188,,,3        !Beam 188 con f.f. cubica
      mp,ex,1,E          !Modulo Young material 1
      mp,nuxy,1,ni        !Coeff poisson material 1
      mp,dens,1,rho        !Densità material 1
      sectype,1,beam,hrec,tubquad    !Sezione tubolare quad
      secdata,wh1,wh1,th1,th1,th1,th1  !Dati sezione tubolare quad
      sectype,2,beam,chan,upn160    !Sezione upn160
      secdata,wu1,wu1,wu2,tu1,tu1,tu2  !Dati sezione upn 160
      sectype,3,beam,rect,staffa    !Sezione staffe
      secdata,bb,bh        !Dati sezione staffe
      et,2,shell63        !Shell63 cassetta
      mp,ex,2,E1          !Modulo Young material 2
      mp,nuxy,2,ni        !Coeff Poisson material 2
      mp,dens,2,rho1        !Densità material 2
      r,1,tc          !Spessore dello shell
      r,2,ws          !Spessore dello Shell delle staffe
      r,3,wcer          !Spessore cerniere
      mp,ex,3,E2          !Modulo di Young material 3 ABS
      mp,nuxy,3,ni2      !Coeff di Poisson material 3 ABS
      mp,dens,3,rho2        !Densità ABS
      r,4,tc,0,0,0,0,0,0,
      rmore,0,0,0,
      rmore
      rmore,mua
       
       
      !Meshing
       
      !Mesh telaio
      esize,0.05
      lsel,r,line,,1,28
      latt,1,,1,,,,1  
      lmesh,all
      lsel,all
       
      lsel,r,line,,30,32
      latt,1,,1,,,,1
      lmesh,all
      lsel,all
       
      lsel,r,line,,29
      k,1000,,-1e+12
      latt,1,,1,,1000,,2
      lmesh,all
      lsel,all
       
      !Mesh staffe
      esize,0.02
      lsel,r,line,,33,40
      latt,1,,1,,,,3
      lmesh,all
      lsel,all
       
      !Mesh cassetta
       
      asel,r,area,,7
      type,2
      real,4
      mat,2
      amesh,all
      allsel,all
       
       
      asel,s,area,,1,6
      type,2
      real,1
      mat,2
      amesh,all
      allsel,all
       
      asel,s,area,,6,17
      type,2
      real,1
      mat,2
      amesh,all
      allsel,all
       
      asel,s,area,,23,27
      type,2
      real,1
      mat,2
      amesh,all
      allsel,all
       
      !Mesh chiusure
      asel,s,area,,18,19
      type,2
      real,3
      mat,3
      amesh,all
      allsel,all
       
      !Mesh cerniere in alluminio
      asel,s,area,,20,22
      type,2
      mat,2
      real,3
      amesh,all
      allsel,all
       
       
      /eshape,1,1
      eplo
       
       
      !vincoli
      ksel,r,kp,,1,4,1
      nslk,r,n,all
      d,all,all
      allsel,all
       
      !Carichi
      allsel,all
       
       
      !ANALISI SPETTRALE
       
      /solu
      antype,modal,new
      modopt,lanb,all,10,500
      mxpand,,,,yes,,,
      allsel,all
      outres,all,all
      outpr,all,all
      save
      solve
      finish
       
      /solu
      antype,spectrum,new
      spopt,psd,alles,no
      !EFINIZIONE SPETTRO DI RISPOSTA DELLA STRUTTURA
      PSDUNIT,1,accg,9.81
      psdfrq,1,,10,40,500
      psdval,1,0.078,0.078,0.0078
      sed,0.0,1.0,0.0
      allsel,all
      pfact,1,base
      psdres,disp,abs
      psdres,velo,abs
      psdres,acel,abs
      allsel,all
      outres,all,all
      outpr,all,all
      save
      solve
      finish
       
      ! ANALISI MODALE PER ESPANDERE I MODI ESTRATTI
      /solu
      antype,spectr
      psdcom,,,,total
      solve
       
       
      /post1
      set,last
      plnsol,s,eqv
       
       
      path,plot,25
      ppath,1,509
      *do,i,2,24
      ppath,i,550+i
      *enddo
      ppath,25,551
      pdef,sigma,s,eqv
      plpath,sigma
    • Chandra Sekaran
      Ansys Employee

      You need to indicate which nodes are going to be excited before issuing PFACT command. IF all the fixed nodes are going to be excited, say, in X direction by the PSD then you can use the below and then use the PFACT.

      ksel,r,kp,,1,4,1
      nslk,r,n,all
      d,all,ux,1   
      allsel,all
      pfact,1,base

       

       

      antype,spectrum,new
      spopt,psd,alles,no
      !EFINIZIONE SPETTRO DI RISPOSTA DELLA STRUTTURA
      PSDUNIT,1,accg,9.81
      psdfrq,1,,10,40,500
      psdval,1,0.078,0.078,0.0078
      sed,0.0,1.0,0.0
      allsel,all
      pfact,1,base
Viewing 1 reply thread
  • You must be logged in to reply to this topic.