## General Mechanical

Topics relate to Mechanical Enterprise, Motion, Additive Print and more

#### Stress strain hysteris loop on Mechanical APDL

Subscriber

Hi, I am looking to simulate uniaxial cyclic loading on a specimen to generate the stress-strain hysteris loop through the loading and unloading phase. I am considering multi-linear hardening for plasticity. Is it possible to achieve this graph using Mechanical APDL?

• John Doyle
Ansys Employee

What is the source of the hysteresis?  Is it rate dependent?  Is it large strain or small strain?  Is it like ratchetting and shakedown?  If so, perhaps you need a Chaboche plasticity model.  Please refer to Section 4.4.4.2.3 of the MAPDL Material Reference Guide for more details.

• Bill Bulat
Ansys Employee

If you don't intend to mimic the shakedown of ratcheting phenomena that John mentioned...

if you're content to model material response that does not change each cycle, then the input below might suffice your needs:

fini
/cle

/vie,1,1,1,1
/vup,1,z
/pbc,u,,1

/sys,del file*.png

C******************************************
C*** PARAMETERS
C******************************************
l=0.100 ! LENGTH
w=0.015 ! WIDTH
t=0.005 ! THICKNESS

E=2e11 ! ELASTIC MODULUS
Sy=2.5e8 ! YIELD STRESS

P=23e5 ! APPLIED PRESSURE

C******************************************
C*** MODEL
C******************************************
/prep7

bloc,,l,,w,,t ! GEOMETRY

et,1,185 ! ELEMENT TYPE, MESH
vmes,all

nsel,s,loc,x ! CONSTRAINTS
nsel,a,loc,x,l
nsel,r,loc,z
d,all,uz
nsel,r,loc,y
d,all,uy
nsel,r,loc,x
d,all,ux

mp,ex,1,E ! DEFINE ELASTIC MODULUS
TB, PLASTIC,1,,4,MISO ! DEFINE MULTILINEAR ISOTROPIC HARDENING
TBPT, ,0,1.00*Sy ! YIELD STRESS
TBPT, ,0.00005,1.10*Sy ! FIRST STRAIN, STRESS POINT
TBPT, ,0.00105,1.20*Sy ! SECOND STRAIN, STRESS POINT
TBPT, ,0.00305,1.25*Sy ! THIRD STRAIN, STRESS POINT

tbli,all,all

fini

C******************************************
C*** SOLVE
C******************************************
/solu

autots,off
nsub,250
outr,all,all
nlge,on

/title,STEP 1: Apply Pressure
nsel,s,loc,z,t,
sf,all,pres,P
alls
save
solve

/title,STEP 2: Ramp Pressure to Zero
nsel,s,loc,z,t,
sf,all,pres,0
alls
save
solve

/title,STEP 3: Reverse Pressure
nsel,s,loc,z,t,
sf,all,pres,-P
alls
save
solve

/title,STEP 4: Ramp Pressure to Zero
nsel,s,loc,z,t,
sf,all,pres,0
alls
save
solve

/title,STEP 5: Apply Pressure
nsel,s,loc,z,t,
sf,all,pres,P
alls
save
solve
fini

C******************************************
C*** POSTPROCESS
C******************************************
/post1
plns,eppl,eqv
/sho,png \$plns,eppl,eqv \$/sho,close \$/wait,2
fini

/post26 ! PLOT STRESS VERSUS STRAIN HYTERESIS LOOP

ansol,2,node(l/2,,-t),s,x ! SX: X COMPONENT ELASTIC STRESS
ansol,3,node(l/2,,-t),eppl,x ! EPPLX: X COMPONENT PLASTIC STRAIN
add,4,2,3,,eptot,,,1/E,1 ! TOTAL X COMPONENT STRAIN = SX/E + EPPLX

/axl,x,Total Strain
/axl,y,X Component Stress
xvar,4
plva,2

/sho,png \$plva,2 \$/sho,close

/eof

Subscriber

Hi Biil,

I am bit confused in implementing the cyclic load. Instead of ramping pressure up and down at each step, I want to used cyclic load with ratcheting phenomena, for example, 100 cycles of stress ratio -1 with frequency of 2. I had a look at Chaboche plasticity model, I will be alright to simulate it but I am not sure to implement the cyclic load.

Subscriber

Thank you Bill. I want to mimic ratcheting on my model as well but this would really help me to kick start my modelling.

Kind regards,