General Mechanical

General Mechanical

Why are my element stress results different?

    • fekl
      Subscriber

      Hello,

      I am modelling curved layered shells using shell281 elements. For postprocessing the results, I am extracting the element stress results (N11, N22, N12, M11, etc.).

      I noticed that there is a large difference in the N11 results, when I change the secoffset between "mid" and "bot". I made a simple model showing the difference (see picture). To keep the geometry the same for both cases, I offset the nodes half of the shell thickness.

      The results are extracted from elements at nearly the same position in both models. The maximum deflection in x direction of the whole model and the extreme stresses in the picked element are very similar for both models. From my understanding, the results should be pretty similar for the stress results as well, but they are not.

      Can somebody explain this deviation?

      I also tried to calculate the N11 results manually by integrating the stresses in x-direction over the laminate thickness, but my results are far off the value given in the SMISC,1 data. Am I missing something important here?

      Thank you very much in advance.

      Kind regards,

      fekl

    • Bill Bulat
      Ansys Employee
      I tried to reproduce your observation with the following APDL input file:
      fini
      /cle

      /sys,del file*.png

      /vie,1,1,2,3
      /esha,1


      C*******************************************
      C*** PARAMETERS
      C*******************************************
      r=0.1 ! BEND RADIUS
      l=0.1 ! LEG LENGTH
      t=0.005 ! THICKNESS
      w=0.1 ! WIDTH

      esz=2*t ! ELEMENT SIZE

      E=2e11 ! ELASTIC MODULUS
      nu=0.3 ! POISSON'S


      C*******************************************
      C*** MODEL
      C*******************************************
      /prep7

      et,1,281 ! ATTRIBUTES
      keyo,1,8,2
      sect,1,shell
      secd,t
      mp,ex,1,E
      mp,nuxy,1,nu

      secof,mid

      k,1 ! GEOMETRY
      k,2,,l
      k,3,-r,l+r
      k,4,-r-l,l+r

      k,5,-r,l

      k,6,,,w

      l,1,2
      l,3,4
      larc,2,3,5,r
      l,1,6

      adra,1,2,3,,,,4
      numm,kp

      esiz,esz ! MESH
      ames,all

      ksel,s,kp,,1,6,5 ! BCs
      lslk,s,1
      nsll,s,1
      d,all,all

      ksel,s,kp,,4,10,6
      lslk,s,1
      nsll,s,1
      f,all,fx,-1

      fini


      C*******************************************
      C*** SOLVE
      C*******************************************
      /solu
      alls
      outr,all,all
      /title,SECOFF,MID
      save
      solv
      fini


      C*******************************************
      C*** POST PROCESS
      C*******************************************
      /post1
      set
      etab,n11,smisc,1
      etab,n22,smisc,2
      plet,n11
      /sho,png $plet,n11 $/sho,close $/wait,2
      plet,n22
      /sho,png $plet,n22 $/sho,close $/wait,2


      C*******************************************
      C*** RESOLVE w/SECOFF,BOT
      C*******************************************
      fini

      /prep7
      secof,bot
      fini

      /solu
      /title,SECOFF,BOT
      save
      solv
      fini

      /post1
      set
      etab,n11,smisc,1
      etab,n22,smisc,2
      plet,n11
      /sho,png $plet,n11 $/sho,close $/wait,2
      plet,n22
      /sho,png $plet,n22 $/sho,close $/wait,2


      The N11 and N22 results for SECOF,MID and SECOF,BOT (image files my input automatically creates) are very similar... it seems that I am so far unable to reproduce your observation. Can you can modify my input in such a way that it DOES show unexpected differences?
      Cheers Bill

    • fekl
      Subscriber
      Dear Bill Thank you very much for your reply! I was not quite able to reproduce the differences with your script, so I used some of your code to adapt my own script. To keep it more simple this time, I left out the correction of the radius to compensate the secoffset. You can find the script below.
      Looking at the global response of the model, the values for N11 and N22 are pretty similar for both secoffset,mid and secoffset,bot. When I look at a specific element, though, the difference is more substantial relative to the absolute values (see the PRETAB results).
      Is there any way to compensate for these errors, e.g. by offsetting the geometry? I tried this in the original post, but did not succeed. To maybe give you some context to my question: I am using the N11, etc. to do some post-processing of laminated composite shells, which are using secoffset,bot. I need to "translate" the extracted loads to the secoffset,mid plane for the post-processing step. From my understanding, it should be sufficient to offset the M11, M22 and M12 moments and leave the N11, N22 and N12 values unchanged. I wanted to check this assumtion using the simple l-bracket model.
      Kind regards fekl

      This is the script I used:
      /clear
      /sys,del file*.png
      /view,1,1,2,3

      /prep7

      length = 0.150
      radius = 0.040
      width = 0.040

      force_ = 10

      K,1,-length,radius,-width/2
      K,2,0,radius,-width/2
      K,3,radius,0,-width/2
      K,4,radius,-length,-width/2

      L,1,2
      CSYS,1
      L,2,3
      CSYS,0
      L,3,4


      K,5,-length,radius,width/2
      L,1,5
      ADRAG,1,2,3,,,,4


      MP,DENS,1,1971.00000 MP,EX,1,13445000000.00000 MP,EY,1,13445000000.00000 MP,EZ,1,11932000000.00000 MP,PRXY,1,0.67000 MP,PRYZ,1,0.20000 MP,PRXZ,1,0.20000 MP,GXY,1,3864600000.00000 MP,GYZ,1,3864600000.00000 MP,GXZ,1,3864600000.00000
      MP,DENS,2,960.00000 MP,EX,2,45000000.00000 MP,EY,2,45000000.00000 MP,EZ,2,45000000.00000 MP,PRXY,2,0.30000 MP,PRYZ,2,0.30000 MP,PRXZ,2,0.30000 MP,GXY,2,22000000.00000 MP,GYZ,2,22000000.00000 MP,GXZ,2,22000000.00000


      ET,1,281
      KEYOPT,1,8,2

      SECTYPE,1,shell
      SECDATA,0.0005,1,0,,skin_1
      SECDATA,0.0040,2,0,,core
      SECDATA,0.0005,1,0,,skin_2
      SECOFFSET,MID

      ESIZE,0.002
      AMESH,all

      /eshape,1
      /replot


      NSEL,s,loc,x,-length
      D,all,all


      NSEL,s,loc,y,-length
      *get,node_count,NODE,0,COUNT
      F,all,fx,force_/node_count

      ALLSEL
      /solu
      solve

      /post1

      SET,first

      ETABLE,N_11,SMISC, 1
      ETABLE,N_22,SMISC, 2
      ETABLE,N_12,SMISC, 3
      ETABLE,M_11,SMISC, 4
      ETABLE,M_22,SMISC, 5
      ETABLE,M_12,SMISC, 6

      ETABLE,Cent_x,CENT,X
      ETABLE,Cent_y,CENT,Y
      ETABLE,Cent_z,CENT,Z

      ESEL,s,,,1836
      NSLE,s
      ESLN,s,0
      NSLE,s
      ESLN,s,0
      NSLE,s
      ESLN,s,0
      plet,N_11
      /sho,png $plet,n_11 $/sho,close $/wait,2

      ESEL,s,,,1836
      NSLE,s
      ESLN,s,0


      PRETAB,N_11,N_22,N_12,M_11,M_22,M_12,Cent_x,Cent_y,Cent_z

      C*******************************************

      C*** RESOLVE w/SECOFF,BOT

      C*******************************************

      fini
      allsel
      /prep7
      secof,bot
      fini
      /solu
      solv
      fini
      /post1
      SET,first
      !RSYS,SOLU

      ETABLE,N_11,SMISC, 1
      ETABLE,N_22,SMISC, 2
      ETABLE,N_12,SMISC, 3
      ETABLE,M_11,SMISC, 4
      ETABLE,M_22,SMISC, 5
      ETABLE,M_12,SMISC, 6

      ETABLE,Cent_x,CENT,X
      ETABLE,Cent_y,CENT,Y
      ETABLE,Cent_z,CENT,Z

      ESEL,s,,,1836
      NSLE,s
      ESLN,s,0
      NSLE,s
      ESLN,s,0
      NSLE,s
      ESLN,s,0
      plet,N_11
      /sho,png $plet,n_11 $/sho,close $/wait,2

      ESEL,s,,,1836
      NSLE,s
      ESLN,s,0


      PRETAB,N_11,N_22,N_12,M_11,M_22,M_12,Cent_x,Cent_y,Cent_z


Viewing 2 reply threads
  • You must be logged in to reply to this topic.